Qt 5.11 | Qt Widgets | Plug & Paint Example | app.pro Example File

Qt 5.11.3 Reference Documentation

# app.pro Example File

tools/plugandpaint/app/app.pro

      TARGET = plugandpaint
      DESTDIR = ..

      QT += widgets

      HEADERS        = interfaces.h \
                       mainwindow.h \
                       paintarea.h \
                       plugindialog.h
      SOURCES        = main.cpp \
                       mainwindow.cpp \
                       paintarea.cpp \
                       plugindialog.cpp

      LIBS           = -L../plugins

      macx-xcode {
          LIBS += -lpnp_basictools$($${QMAKE_XCODE_LIBRARY_SUFFIX_SETTING})
      } else {
          LIBS += -lpnp_basictools
          if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
              mac:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)_debug
              win32:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)d
          }
      }

      # install
      target.path = $$[QT_INSTALL_EXAMPLES]/widgets/tools/plugandpaint
      INSTALLS += target

      CONFIG += install_ok  # Do not cargo-cult this!